Das Bewegungs­radio

#include <WiFi.h>
#include "Audio.h"

#define PIR_PIN  5
#define AMP_SD   12
#define I2S_BCLK 9
#define I2S_LRC  10
#define I2S_DOUT 11

const char* ssid   = "DEIN_WLAN";
const char* pass   = "DEIN_PASSWORT";
const char* stream = "http://STREAM-URL";
const unsigned long NACHLAUF = 3UL * 60 * 1000; // 3 Minuten

Audio audio;
unsigned long letzteBewegung;

void schlafen() {
  audio.stopSong();
  digitalWrite(AMP_SD, LOW);              // Verstärker aus
  WiFi.disconnect(true);
  esp_sleep_enable_ext0_wakeup((gpio_num_t)PIR_PIN, 1);
  esp_deep_sleep_start();
}

void setup() {
  pinMode(PIR_PIN, INPUT);
  pinMode(AMP_SD, OUTPUT);
  digitalWrite(AMP_SD, HIGH);             // Verstärker an

  WiFi.begin(ssid, pass);
  unsigned long t = millis();
  while (WiFi.status() != WL_CONNECTED) {
    if (millis() - t > 15000) schlafen(); // kein WLAN → schlafen
    delay(200);
  }
  audio.setPinout(I2S_BCLK, I2S_LRC, I2S_DOUT);
  audio.setVolume(12);                     // 0–21
  audio.connecttohost(stream);
  letzteBewegung = millis();
}

void loop() {
  if (digitalRead(PIR_PIN) == HIGH) letzteBewegung = millis();
  if (millis() - letzteBewegung > NACHLAUF) schlafen();
  audio.loop();
}